spherestudio/sphereStudioSetup.iss at master · Radnen/spherestudio · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
; Sphere Studio Setup Script for Inno Setup
; Builds a Windows installer distribution of Sphere Studio.
; Copyright (c) 2021 Spherical

#define AppName "Sphere Studio"
#define AppPublisher "Fat Cerberus"
#define AppVersion3 "2.1.0 WiP"
#define AppVersion4 "2.1.0.0"

[Setup]
OutputBaseFilename=sphereStudioSetup-{#AppVersion3}-msw
OutputDir=.
AppId={{F40892B0-C96E-48B7-B1E9-8C2BFB6C167D}
AppCopyright=© 2021 Fat Cerberus
AppName={#AppName}
AppPublisher={#AppPublisher}
AppPublisherURL=http://www.spheredev.org/
AppSupportURL=http://forums.spheredev.org/
AppUpdatesURL=http://forums.spheredev.org/index.php/topic,24.0.html
AppVerName={#AppName} {#AppVersion3}
AppVersion={#AppVersion4}
ArchitecturesInstallIn64BitMode=x64 ia64
ChangesAssociations=yes
Compression=lzma2
DefaultDirName={autopf}\{#AppName}
DisableProgramGroupPage=yes
LicenseFile=LICENSE.txt
SetupIconFile=SphereStudioIDE\Sphere Studio.ico
SolidCompression=yes
UninstallDisplayName={#AppName}
UninstallDisplayIcon={app}\SphereStudioIDE.exe,0
VersionInfoDescription={#AppName} {#AppVersion3} Setup for Windows
VersionInfoVersion={#AppVersion4}

[Languages]
Name: "english"; MessagesFile: "compiler:Default.isl"

[Files]
Source: "SphereStudioIDE\bin\Release\SphereStudioIDE.exe"; DestDir: "{app}"; Flags: ignoreversion
Source: "SphereStudioIDE\bin\Release\SphereStudio.Base.xml"; DestDir: "{app}"; Flags: ignoreversion
Source: "SphereStudioIDE\bin\Release\*.config"; DestDir: "{app}"; Flags: ignoreversion
Source: "SphereStudioIDE\bin\Release\*.dll"; DestDir: "{app}"; Flags: ignoreversion
Source: "SphereStudioIDE\bin\Release\*.xml"; DestDir: "{app}"; Flags: ignoreversion
Source: "SphereStudioIDE\bin\Release\Dictionary\*"; DestDir: "{app}\Dictionary"; Flags: ignoreversion
Source: "SphereStudioIDE\bin\Release\Plugins\*.dll"; DestDir: "{app}\Plugins"; Flags: ignoreversion

[Registry]
Root: HKCR; Subkey: ".ssproj"; ValueType: string; ValueName: ""; ValueData: "SphereStudio.SSPROJ"; Flags: uninsdeletevalue
Root: HKCR; Subkey: "SphereStudio.SSPROJ"; ValueType: string; ValueName: ""; ValueData: "Sphere Studio Project"; Flags: uninsdeletekey
Root: HKCR; Subkey: "SphereStudio.SSPROJ\DefaultIcon"; ValueType: string; ValueName: ""; ValueData: "{app}\SphereStudioIDE.exe,0"
Root: HKCR; Subkey: "SphereStudio.SSPROJ\shell\open\command"; ValueType: string; ValueName: ""; ValueData: """{app}\SphereStudioIDE.exe"" ""%1"""

[Icons]
Name: "{commonprograms}\{#AppName}"; Filename: "{app}\SphereStudioIDE.exe"

[Run]
Filename: "{app}\SphereStudioIDE.exe"; Description: "{cm:LaunchProgram,{#StringChange(AppName, '&', '&&')}}"; Flags: nowait postinstall skipifsilent

[Code]
procedure InitializeWizard;
begin
  WizardForm.LicenseAcceptedRadio.Checked := True;
end;