YetAnotherMessagesLibrary/settings.gradle at master · Mythic-Projects/YetAnotherMessagesLibrary · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
rootProject.name = 'YetAnotherMessagesLibrary'

this.setupSubproject("tools")
this.setupSubproject("core")

// Platforms
this.setupSubproject("platform")
this.setupSubproject("platform:bukkit", "platform-bukkit")
this.setupSubproject("platform:velocity", "platform-velocity")

// Repositories (Data Supplier)
this.setupSubproject("repository")
this.setupSubproject("repository:okaeri", "repository-okaeri")

// Replaceable (Placeholders)
this.setupSubproject("replaceable")
this.setupSubproject("replaceable:okaeri", "replaceable-okaeri")
this.setupSubproject("replaceable:placeholderapi", "replaceable-placeholderapi")

// Code examples
this.setupSubproject("example")

def setupSubproject(String project, String name) {
    include "$project"
    findProject(":$project")?.name = name
}

def setupSubproject(String project) {
    this.setupSubproject(project, project)
}

dependencyResolutionManagement {
    versionCatalogs {
        libs {
            library("spigot", "org.spigotmc:spigot-api:1.12.2-R0.1-SNAPSHOT")
            library("velocity", "com.velocitypowered:velocity-api:3.4.0-SNAPSHOT")
        }
        adventure {
            String apiVersion = "4.26.1"
            library("api", "net.kyori:adventure-api:${apiVersion}")
            library("serializer-legacy", "net.kyori:adventure-text-serializer-legacy:${apiVersion}")
            library("serializer-minimessage", "net.kyori:adventure-text-minimessage:${apiVersion}")

            String platformVersion = "4.4.1"
            library("platform-bukkit", "net.kyori:adventure-platform-bukkit:${platformVersion}")
        }
        okaeri {
            library("config", "eu.okaeri:okaeri-configs-core:6.0.0-beta.27")
            library("placeholders", "eu.okaeri:okaeri-placeholders-core:5.1.2")
        }
    }
}