Utils/settings.gradle at master · MinecraftForge/Utils · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
plugins {
    id 'org.gradle.toolchains.foojay-resolver-convention' version '1.0.0'
}

rootProject.name = 'utils'

enableFeaturePreview 'TYPESAFE_PROJECT_ACCESSORS'

include 'hash-utils'
include 'json-data-utils'
include 'file-utils'
include 'log-utils'
include 'os-utils'
include 'download-utils', 'download-utils:download-utils-j11'

// Applying plugins causes them to not have any IDE support when also applied to any build.gradle files
// The workaround for now is to use this listener here so that it can stay in settings.gradle
// See: https://youtrack.jetbrains.com/issue/IDEA-332061/Gradle-Missing-Code-Completion-Suggestions-for-Settings-Plugins-in-Groovy-DSL
gradle.beforeProject { Project project ->
    project.pluginManager.withPlugin('net.minecraftforge.gradleutils') {
        project.repositories {
            mavenCentral()
            gradlePluginPortal()
            maven project.gradleutils.forgeMaven
            //mavenLocal()
        }
    }
}

//@formatter:off
dependencyResolutionManagement.versionCatalogs.register('libs') {
    // Plugins
    plugin 'licenser',      'net.minecraftforge.licenser'      version '1.2.0'
    plugin 'gradleutils',   'net.minecraftforge.gradleutils'   version '3.3.21'
    plugin 'gitversion',    'net.minecraftforge.gitversion'    version '3.1.6'
    plugin 'changelog',     'net.minecraftforge.changelog'     version '3.1.3'
    plugin 'multi-release', 'net.minecraftforge.multi-release' version '0.1.4'

    // Static Analysis
    library 'nulls', 'org.jetbrains', 'annotations' version '26.0.2-1'

    // Files
    library 'commons-io', 'commons-io',         'commons-io' version '2.18.0'
    library 'srgutils',   'net.minecraftforge', 'srgutils' version '0.5.11'

    // Data
    library 'gson', 'com.google.code.gson', 'gson' version '2.10.1'


    //region Testing
    version 'junit', '5.10.2'
    library 'junit-api',               'org.junit.jupiter',  'junit-jupiter-api'       versionRef 'junit'
    library 'junit-engine',            'org.junit.jupiter',  'junit-jupiter-engine'    versionRef 'junit'
    library 'junit-platform-launcher', 'org.junit.platform', 'junit-platform-launcher' version    '1.10.2'
    bundle 'junit-runtime', ['junit-engine', 'junit-platform-launcher']
    //endregion
}
//@formatter:on